使用TListBox获取“OnChange”类型的功能有诀窍吗？我可以子类化组件并添加属性等,然后只有当索引发生变化时才执行OnClick代码…我也可以使用表单级变量来存储当前索引,但只是想知道我是否忽略了之前的我走了一路或另一路.
解决方法
似乎除了自己实现这一点之外别无他法.你需要的是记住当前选择的项目,每当
ItemIndex属性从代码更改或控件收到
LBN_SELCHANGE通知(当前触发
OnClick事件)时,您将比较您存储的项目索引与当前项目索引选中,如果它们不同,则触发您自己的OnChange事件.在插入类的代码中,它可以是：
type
TListBox = class(StdCtrls.TListBox)
private
FItemIndex: Integer;
FOnChange: TNotifyEvent;
procedure CNCommand(var AMessage: TWMCommand); message CN_COMMAND;
protected
procedure Change; virtual;
procedure SetItemIndex(const Value: Integer); override;
published
property OnChange: TNotifyEvent read FOnChange write FOnChange;
end;
implementation
{ TListBox }
procedure TListBox.Change;
begin
if Assigned(FOnChange) then
FOnChange(Self);
end;
procedure TListBox.CNCommand(var AMessage: TWMCommand);
begin
inherited;
if (AMessage.NotifyCode = LBN_SELCHANGE) and (FItemIndex <> ItemIndex) then
begin
FItemIndex := ItemIndex;
Change;
end;
end;
procedure TListBox.SetItemIndex(const Value: Integer);
begin
inherited;
if FItemIndex <> ItemIndex then
begin
FItemIndex := ItemIndex;
Change;
end;
end;