我试图用这种格式读取一个ini文件：
[SectionName] total=4 [AnotherSectionName] total=7 [OtherSectionName] total=12
基本上我想从ini文件中回显出某些值(例如，在OtherSectionName下的总数，后面是来自AnotherSectionName的总数)。
这是一个命令文件(ini.cmd)，您可以使用它来提取相关值：
@setlocal enableextensions enabledelayedexpansion
@echo off
set file=%~1
set area=[%~2]
set key=%~3
set currarea=
for /f "usebackq delims=" %%a in ("!file!") do (
set ln=%%a
if "x!ln:~0,1!"=="x[" (
set currarea=!ln!
) else (
for /f "tokens=1,2 delims==" %%b in ("!ln!") do (
set currkey=%%b
set currval=%%c
if "x!area!"=="x!currarea!" if "x!key!"=="x!currkey!" (
echo !currval!
)
)
)
)
endlocal
这是一个抄本显示它在行动(我手动缩进输出，使其更容易阅读)：
c:\src>type ini.ini
[SectionName]
total=4
[AnotherSectionName]
total=7
[OtherSectionName]
total=12
c:\src>ini.cmd ini.ini SectionName total
4
c:\src>ini.cmd ini.ini AnotherSectionName total
7
c:\src>ini.cmd ini.ini OtherSectionName total
12
要在另一个cmd文件中实际使用这个，只需将下面的echo％val％行替换成你想要做的任何事情)：
for /f "delims=" %%a in ('call ini.cmd ini.ini AnotherSectionName total') do (
set val=%%a
)
echo %val%